La procédure GREPLAY permet d’associer plusieurs graphiques en un seul, en jouant sur leurs emplacements et leur distribution. Elle utilise des mises en forme prédéfinies, les templates. Voici une petite introduction à son fonctionnement.

Étape n° 1 : générer des graphiques et les sauvegarder

Les graphiques SAS sont stockés dans des catalogues, sous formes d’entrées de type GRSEG. Pour choisir le nom et l’emplacement de ces sauvegardes, il faut ajouter aux procédures graphiques deux options :

1. GOUT qui est le nom du catalogue de stockage (WORK.GSEG par défaut), au niveau de l’instruction PROC Gxxx ;
2. NAME qui est le nom de l’entrée correspondant à chaque graphique (les noms par défaut dépendent de la procédure), au niveau de l’instruction graphique proprement dite (PLOT, BUBBLE, VBAR, HBAR, PIE).

PROC GCHART DATA = sashelp.prdsale
            GOUT = work.graphiques ;
    VBAR country / SUMVAR = actual
                     NAME = "pays" ;
    VBAR product / SUMVAR = actual
                     NAME = "produit" ;
RUN ; QUIT ;

Dans le catalogue WORK.GRAPHIQUES, on a désormais deux entrées, PAYS.GRSEG et PRODUIT.GRSEG.

Étape n°2 : choisir son template

L’ensemble des templates fournis par SAS sont stockés dans SASHELP.TEMPLT. Il est possible d’en définir d’autres, également à travers la procédure GREPLAY.

Si leurs noms ne vous semblent pas explicites, vous pouvez afficher leur description (dans le menu VIEW>DETAILS, ou pour les versions en français, AFFICHAGE>DETAILS) : ci-dessous le résultat (cliquer sur l’image pour la voir en plus grande résolution).

Étape n°3 : rejouer les graphiques avec GREPLAY

La procédure GREPLAY permet de combiner des graphiques existants et un template pour combiner plusieurs graphiques en une seule image. Les données de base, elles, ne sont pas relues : il ne s’agit que de manipulation d’images déjà produites.

C’est la raison pour laquelle l’aspect final des graphiques ne peut pas bénéficier des améliorations esthétiques des drivers ActiveX, image ActiveX, Java et image Java. Les graphiques produits ainsi, un peu moches, ont l’aspect limité des graphiques dans des versions antérieures de SAS.

PROC GREPLAY NOFS TC = catalogue_de_templates
               IGOUT = catalogue_de_graphiques ;
   TEMPLATE = nom_du_template ;
   TREPLAY 1: nom_du_graphique
           2: nom_du_graphique
       etc.
   ;
RUN ; QUIT ;

Voici les deux graphiques précédents mis côte à côte avec un espace entre les deux.

PROC GREPLAY NOFS TC = sashelp.templt
               IGOUT = work.graphiques ;
     TEMPLATE = h2s ;
     TREPLAY 1: pays
             2: produit ;
RUN ; QUIT ;

(cliquer sur l’image pour la voir en plus grande résolution)